100 'IBMBOS.BAS VERSION 5.00
110 'Author:Tom,Ka-chun
120 'Time  :20.16.00.00
130 'Date  :04-12-1987
140 'Copyright Parman Personal Computer Company Limited
150 'Copyright Parman Personal Computer Programming Division
160 'Licensed Material
170 KEY OFF:SCREEN 0,0,0:WIDTH 80:CLS:DEF SEG=0
180 DRIVE$=CHR$(65+PEEK(1284)+":"
190 DIRECTORY$="\"
200 EXTENSION$=".BAS"
210 FILENAME$="*"
220 DEF SEG:BLOAD "KEY_1.KEY",80
230 ON ERROR GOTO 760
240 SHELL "CLS"
250 M$="Enter edit mode: 1=RUN 2=LOAD 3=RENAME 4=DELETE 5=EXIT 6=SYSTEM 7=COPY 8=CHANGE OPTION 9=USE DOS Command..."
260 SCREEN 0,0,1,1:CLS:LOCATE 1,1
270 PRINT "Parman BOS Version 5.00"
280 PRINT "Copyright Parman Computer & Software Company"
290 PRINT "-- Programming Department"
300 PRINT "Parman BASIC Version A2.30"
310 PRINT "DOS Version 3.20"
320 PRINT:PRINT FRE("")"bytes free"
330 PRINT
340 PRINT "1. Default drive is "DRIVE$
350 PRINT "2. Default directory is "DIRECTORY$
360 PRINT "3. Default filename is "FILENAME$
370 PRINT "4. Default extension is "EXTENSION$
380 PRINT "5. Today's date is "DATE$
390 PRINT "6. The time now is "TIME$
400 PRINT:PRINT "Press the number you want to change or 0 to remain unchange"
410 A$=INKEY$:IF A$<"0" OR A$>"6" THEN 320
420 ON VAL(A$)+1 GOSUB 500,440,450,460,470,480,490
430 GOTO 260
440 PRINT "Enter new drive: ":DRIVE$=INPUT$(1)+":":RETURN
450 INPUT "Enter new directory: ",DIRECTORY$:RETURN
460 INPUT "Enter new filename: ",FILENAME$:RETURN
470 INPUT "Enter new extension: ",EXTENSION$:EXTENSION$="."+EXTENSION$:RETURN
480 PRINT "Today's date is"DATE$:INPUT "Enter new date: ",D$:DATE$=D$:RETURN
490 PRINT "The time now is"TIME$:INPUT "Enter new time: ",T$:TIME$=T$:RETURN
500 SCREEN 0,0,0,0:CLS
510 FILES DRIVE$+DIRECTORY$+FILENAME$+EXTENSION$
520 X=CSRLIN
530 LOCATE X,1:PRINT LEFT$(M$,79);
540 I$=INKEY$:IF NOT(I$<"1" OR I$>"9") THEN 570
550 M$=MID$(M$,2,LEN(M$)-1)+LEFT$(M$,1)
560 GOTO 530
570 PRINT:ON VAL(I$)-1 GOTO 590,600,610,620,630,640,690,710
580 GOSUB 700:LOAD F$,R:GOTO 590
590 GOSUB 700:CLS:LOAD F$:END
600 GOSUB 700:INPUT "Enter new filename (with extension)";N$:NAME F$ AS N$:GOTO 500
610 GOSUB 700:KILL F$:GOTO 500
620 CLS:KEY ON:NEW:END
630 IF E=1 THEN 770 ELSE CLS:SHELL "cls":SHELL:CLS:RUN
640 IF E=1 THEN 770 ELSE GOSUB 700
650 INPUT "Enter target drive specification";D$
660 COMMAND$="copy "+F$+" "+D$
670 GOSUB 750:CLS
680 RETURN
690 CLS:GOTO 260
700 PRINT"Enter filename (with extension)":GOSUB 810:RETURN
710 INPUT"Enter DOS Command - ",COMMAND$:IF COMMAND$=""THEN 500 ELSE CLS
720 GOSUB 750
730 I$=INKEY$:IF I$="" THEN 730
740 GOTO 500
750 SHELL"cls":SHELL COMMAND$:RETURN
760 IF ERR=76 THEN M$="Enter edit mode: 1=RUN 2=LOAD 3=RENAME 4=DELETE 5=EXIT 8=CHANGE OPTION... ":E=1:GOTO 260 ELSE 790
770 IF ERR=76 THEN PRINT"You cannot shell to DOS because you are now in top level.":PRINT"Insert DOS diskette and press <Ctrl> <Alt> <Del> to restart." ELSE 790
780 GOTO 780
790 IF ERR=53 THEN PRINT"File not found!":BEEP:PRINT"Press any key to continue...":I$=INPUT$(1):RESUME 270
800 PRINT"Error found in Line "ERL:PRINT"Error Code is "ERR:PRINT"Program Halted":ON ERROR GOTO 0:STOP
810 Y=2:X=13:Y1=Y:X1=X
820 LOCATE Y1,X1:PRINT"  ":LOCATE Y,X:PRINT"<=":X1=X:Y1=Y:I$=INKEY$:IF I$="" THEN 820 ELSE I$=RIGHT$(I$,1):I$=CHR$(ASC(I$)AND 127+32*(I$>"Z")-64*(I$<" "))
830 IF I$="T"THEN LOCAT 25:INPUT"[Enter by text";F$:IF F$="" THEN RETURN 500 ELSE RETURN
840 IF I$=CHR$(13)THEN F$="":FOR J=12 to 1 STEP -1:F$=F$+CHR$(SCREEN(Y,X-J)):NEXT J:RETURN
850 IF I$="G"THEN Y=2:X=13
860 IF I$="H"THEN Y=Y-1:IF Y<2 THEN Y=20
870 IF I$="I"THEN Y=Y-5:IF Y<2 THEN Y=20
880 IF I$="K"THEN X=X-18:IF X<1 THEN X=67:Y=Y-1:IF Y<2 THEN Y=20
890 IF I$="M"THEN X=X+18:IF X>67 THEN X=13:Y=Y+1:IF Y>20 THEN Y=2
900 IF I$="O"THEN Y=20:X=67
910 IF I$="P"THEN Y=Y+1:IF Y>20 THEN Y=1
920 IF I$="Q"THEN Y=Y+5:IF Y>20 THEN Y=1
930 IF I$=CHR$(27)THEN RETURN 500
940 GOTO 820